X-Git-Url: http://cvs.zerfleddert.de/cgi-bin/gitweb.cgi/proxmark3-svn/blobdiff_plain/16e590fd2bb6a8c8354ba49722d85677da828f76..127f149075522b280d66dbe3d11130151fd8bdcc:/armsrc/ldscript

diff --git a/armsrc/ldscript b/armsrc/ldscript
index 0489cfe4..34da26bc 100644
--- a/armsrc/ldscript
+++ b/armsrc/ldscript
@@ -1,13 +1,67 @@
-ENTRY(Vector)
-SECTIONS
-{
-	. = 0x00010000;
-	.start : { obj/start.o(.text) }
-	.text : { *(.text) }
-	.rodata : { *(.rodata) }
-	. = 0x00200000;
-	.data : { *(.data) }
-	__bss_start__ = .;
-	.bss : { *(.bss) }
-	__bss_end__ = .;
-}
+/*
+-----------------------------------------------------------------------------
+ This code is licensed to you under the terms of the GNU GPL, version 2 or,
+ at your option, any later version. See the LICENSE.txt file for the text of
+ the license.
+-----------------------------------------------------------------------------
+ Linker script for the ARM binary
+-----------------------------------------------------------------------------
+*/
+INCLUDE ../common/ldscript.common
+
+PHDRS
+{
+	text PT_LOAD FLAGS(5);
+	data PT_LOAD;
+	bss PT_LOAD;
+}
+
+ENTRY(Vector)
+SECTIONS
+{
+	.start : {
+		*(.startos)
+	} >osimage :text
+
+	.text : {
+		KEEP(*(stage1_image))
+		*(.text)
+		*(.text.*)
+		*(.eh_frame)
+		*(.glue_7)
+		*(.glue_7t)
+	} >osimage :text
+
+	.rodata : {
+		*(.rodata)
+		*(.rodata.*)
+		*(fpga_all_bit.data)
+		KEEP(*(.version_information))
+		. = ALIGN(8);
+	} >osimage :text
+
+	.data : {
+		KEEP(*(compressed_data))
+		*(.data)
+		*(.data.*)
+		*(.ramfunc)
+		. = ALIGN(4);
+	} >ram AT>osimage :data
+
+	__data_src_start__ = LOADADDR(.data);
+	__data_start__ = ADDR(.data);
+	__data_end__ = __data_start__ + SIZEOF(.data);
+	__os_size__ = SIZEOF(.text) + SIZEOF(.data) + SIZEOF(.rodata);
+	
+	.bss : {
+		__bss_start__ = .; 
+		*(.bss)
+		*(.bss.*) 
+		. = ALIGN(4);
+		__bss_end__ = .;
+	} >ram AT>ram :bss
+
+	.commonarea (NOLOAD) : {
+		*(.commonarea)
+	} >commonarea :NONE
+}