cvs.zerfleddert.de Git - proxmark3-svn/blob - common/ldscript.common

   1 /*
   2 -----------------------------------------------------------------------------
   3  This code is licensed to you under the ter
   4 ms of the GNU GPL, version 2 or,
   5  at your option, any later version. See the LICENSE.txt file for the text of
   6  the license.
   7 -----------------------------------------------------------------------------
   8  Common linker script
   9 -----------------------------------------------------------------------------
  10 */
  11
  12 /* AT91SAM7S256 has 256k Flash and 64k RAM */
  13 /* AT91SAM7S512 has 512k Flash and 64k RAM */
  14 MEMORY
  15 {
  16         bootphase1 : ORIGIN = 0x00100000, LENGTH = 0x200             /* Phase 1 bootloader: Copies real bootloader to RAM */
  17         bootphase2 : ORIGIN = 0x00100200, LENGTH = 0x2000 - 0x200    /* Main bootloader code, stored in Flash, executed from RAM */
  18         osimage    : ORIGIN = 0x00102000, LENGTH = 512K - 0x2000     /* Place where the main OS will end up */
  19         ram        : ORIGIN = 0x00200000, LENGTH = 64K - 0x20        /* RAM, minus small common area */
  20         commonarea : ORIGIN = 0x00200000 + 64K - 0x20, LENGTH = 0x20 /* Communication between bootloader and main OS */
  21 }
  22
  23 /* Export some information that can be used from within the firmware */
  24 _bootphase1_version_pointer = ORIGIN(bootphase1) + LENGTH(bootphase1) - 0x4;
  25 _osimage_entry = ORIGIN(osimage);
  26 _bootrom_start = ORIGIN(bootphase1);
  27 _bootrom_end = ORIGIN(bootphase2) + LENGTH(bootphase2);
  28 _flash_start = ORIGIN(bootphase1);
  29 _flash_end = ORIGIN(osimage) + LENGTH(osimage);
  30 _stack_end = ORIGIN(ram) + LENGTH(ram) - 8;